initial commit

2026-08-18 13:34:11 +02:00
commit 48fa1052ad
9 changed files with 449 additions and 0 deletions
@@ -0,0 +1,72 @@
+{
+  description = "Wordle-Solver";
+
+  inputs = {
+    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
+    flake-parts.url = "github:hercules-ci/flake-parts";
+    rust-overlay = {
+      url = "github:oxalica/rust-overlay";
+      inputs.nixpkgs.follows = "nixpkgs";
+    };
+    crate2nix = {
+      url = "github:nix-community/crate2nix";
+      inputs.nixpkgs.follows = "nixpkgs";
+    };
+  };
+
+  outputs = inputs @ {
+    flake-parts,
+    crate2nix,
+    rust-overlay,
+    ...
+  }:
+    flake-parts.lib.mkFlake {inherit inputs;} {
+      systems = [
+        "aarch64-linux"
+        "aarch64-darwin"
+        "x86_64-darwin"
+        "x86_64-linux"
+      ];
+
+      perSystem = {
+        pkgs,
+        system,
+        self',
+        ...
+      }: let
+        # Use rust-bin to generate the toolchain from rust-toolchain.toml
+        rust-toolchain = pkgs.rust-bin.fromRustupToolchainFile ./rust-toolchain.toml;
+
+        buildRustCrateForPkgs = _:
+          pkgs.buildRustCrate.override {
+            rustc = rust-toolchain; # Use rustc from toolchain
+            cargo = rust-toolchain; # Use cargo from toolchain
+          };
+
+        # Cargo.nix for IFD
+        generatedCargoNix = crate2nix.tools.${system}.generatedCargoNix {
+          name = "rustnix";
+          src = ./.;
+        };
+
+        cargoNix = import generatedCargoNix {
+          inherit pkgs buildRustCrateForPkgs;
+        };
+      in {
+        # Overlay pkgs with rust-bin
+        _module.args.pkgs = import inputs.nixpkgs {
+          inherit system;
+          overlays = [(import rust-overlay)];
+        };
+
+        packages = {
+          wordle-solver = cargoNix.rootCrate.build;
+          default = self'.packages.wordle-solver;
+        };
+
+        devShells.default = pkgs.mkShell {
+          buildInputs = [rust-toolchain];
+        };
+      };
+    };
+}