{
  stdenv,
  lib,
  fetchFromGitHub,
  gitUpdater,
  kdeclarative,
  libplasma,
  plasma-workspace,
}:
stdenv.mkDerivation {
  pname = "layan-kde-qt6";
  version = "2025-02-13";
  src = fetchFromGitHub {
    owner = "vinceliuice";
    repo = "Layan-kde";
    rev = "ace0b1d93e5f08c650630c146b2d637e1e2e6cd1";
    hash = "sha256-T69bGjfZeOsJLmOZKps9N2wMv5VKYeo1ipGEsLAS+Sg=";
  };

  # Propagate sddm theme dependencies to user env otherwise sddm does
  # not find them. Putting them in buildInputs is not enough.
  propagatedUserEnvPkgs = [
    kdeclarative
    libplasma
    plasma-workspace
  ];

  postPatch = ''
    patchShebangs install.sh

    substituteInPlace install.sh \
      --replace '$HOME/.local' $out \
      --replace '$HOME/.config' $out/share
  '';

  installPhase = ''
    runHook preInstall

    name= ./install.sh --dest $out/share/themes

    runHook postInstall
  '';

  passthru.updateScript = gitUpdater {};

  meta = with lib; {
    description = "Flat Design theme for KDE Plasma desktop";
    homepage = "https://github.com/vinceliuice/Layan-kde";
    license = licenses.gpl3Only;
    platforms = platforms.all;
  };
}
